Excelを使ったタートルズトレード流『Excelの資産運用ログ』の作り方

Excelの資産運用ログ

1980年代、米国の伝説的相場師が「素人を一流のトレーダーに育成できるか？」という賭けを行い、実際に大成功を収めた育成プログラム――タートルズトレード。

筆者は投資の専門家ではないため、その理論のすべてを精緻に解説する知識は持ち合わせていないが、浅学ながらそこから教えられたのは、勘や感情に頼らず「あらかじめ決めたルールに100%従うこと」の重要性だった。

『Excelの資産運用ログ』は、そのタートルズの教えを「資産管理の規律」として自分なりに解釈し、Excelに落とし込んだものである。

今回はその『Excelの資産運用ログ』の作り方を撰述していく。

【本記事の内容に関するご注意】

本記事は、筆者が実際に運用しているExcelログシステムの「構築手順」を紹介しているものであり、特定の銘柄の売買を推奨したり、投資を勧誘したりするものではありません。
本システムの構築・運用をされる場合は、以下の免責事項をご一読・ご了承いただいた上で進めてください。

システムの仕様について：
記事内で紹介する数式やロジックは、筆者の作業環境における一例です。ExcelのバージョンやOSの仕様、また証券会社ごとの計算方式（端数処理等）により、実際の数値と差異が生じる可能性があります。

自己責任でのご利用：
投資には元本割れのリスクが伴います。本システムに表示される数値は、あくまで「タートルズトレード」の概念を参考に算出した目安であり、同手法の完全な再現や有効性を保証するものではありません。将来の利益を保証するものではない点をご理解ください。

ご了承のお願い：
本記事の内容を参考にシステムの構築や運用を行われる場合は、すべて読者ご自身の責任において行っていただきますようお願い申し上げます。 本記事を読み進め、構築作業を開始された場合は、これらの免責事項をご理解・ご了承いただいたものとさせていただきます。

本記事はWindows版Excel 2021を基に解説しています。
Excel 365やMac版をご利用の場合、一部表示や機能に違いがある場合があります。

◆

◆

『Excelの資産運用ログ』の作り方

『Excelの資産運用ログ』は4枚のシートから構成されている。

◆

『Excelの資産運用ログ』――「商品・資産管理」シートの作成手順

『Excelの資産運用ログ』における「商品・資産管理」シートは、保有する商品と購入予定の現在価格、またその時点のATRを入力することで、自身が投入すべき数量や金額を計算してくれる設計となっている。

  • Excelで新規ファイルを作成し、シート名を「商品・資産管理」に変更する
  • 各セルに見出しとなる単語を入力していく
    • A1:総投資用資金:　A2:リスク比率:　A3:許容リスク:
      A4:グループ　B4:CD　C4:コード　D4:商品名
      E4:参考価格　F4:ATR　G4:1ユニット　H4:1ユニット価額　I4:メモ
  • A4からI4までを範囲選択して[挿入]タブから[テーブル]をクリック
    • [先頭行をテーブルの見出しとして使用する]にチェックをつけて[OK]をクリック
  • [テーブルデザイン]タブを開き[テーブル名:]に「tblItem」と入力
  • 以下の対象セルに数式を入力
    • B3：総投資用資金とリスク比率から許容リスク額を計算して表示 
      • =B1*B2
    • G5：許容リスク・現在価格・ATRからその商品の1ユニット数量を計算 
      • =IFERROR(IF([@グループ]="4_暗号資産",ROUNDDOWN($B$3/[@ATR],8),ROUNDDOWN($B$3/[@ATR],0)),"")
    • H5：その商品の1ユニットの額を計算 
      • =IF([@1ユニット]="", "", [@参考価格] * [@1ユニット])
  • [商品名]をリスト化する
    • D列全体を範囲選択したあと、Ctrlキーを押しながらD1からD4までを一つずつ左クリックで範囲選択解除していく
    • [名前ボックス]に「商品名」と入力して確定
  • 金額が表示される列やセルは、右クリックの[セルの書式設定]から表示形式を変更しておくのがおススメ
    • 金額表示列：B1セル・B3セル・E列（参考価格）・F列（ATR）・H列（1ユニット価額）
「商品・資産管理」シートの作成手順
  • ①
    Excelで新規ファイルを作成し、シート名を「商品・資産管理」に変更する
  • ②
    各セルに見出しとなる単語を入力していく

    A1:総投資用資金:　A2:リスク比率:　A3:許容リスク:
    A4:グループ　B4:CD　C4:コード　D4:商品名
    E4:参考価格　F4:ATR　G4:1ユニット　H4:1ユニット価額　I4:メモ

  • ③
    A4からI4までを範囲選択して[挿入]タブから[テーブル]をクリック

    [先頭行をテーブルの見出しとして使用する]にチェックをつけて[OK]をクリック

  • ④
    [テーブルデザイン]タブを開き[テーブル名:]に「tblItem」と入力
  • ⑤
    以下の対象セルに手順⑤の数式を入力
  • ⑥
    [商品名]をリスト化する

    D列全体を範囲選択したあと、Ctrlキーを押しながらD1からD4までを一つずつ左クリックで範囲選択解除していく

    [名前ボックス]に「商品名」と入力して確定

  • ⑦
    金額が表示される列やセルは、右クリックの[セルの書式設定]から表示形式を変更しておくのがおススメ

    金額額表示列：B1セル・B3セル・E列（参考価格）・F列（ATR）・H列（1ユニット価額）

「商品・資産管理」シートの使い方は、「Excelを使ったタートルズトレード流『Excelの資産運用ログ』の使い方」にて解説している。

Excelを使ったタートルズトレード流『Excelの資産運用ログ』の使い方
タートルズ流の投資手法を参考にした『Excelの資産運用ログ』システムを公開。おまかせ運用の投資が主流の今、あえて自作Excelで管理する筆者の事例を提示する。
senjutsu-automatos.com

◆

『Excelの資産運用ログ』――「取引ログ」シートの作成手順

  • 新しいシートを作成して、シート名を「取引ログ」に変更する
  • 各セルに見出しとなる単語を入力していく
    • A1:総投資用資金:　A2:現投入資金:　A3:年　B3:日付
      C3:区分　D3:売買　E3:グループ　F3:CD
      G3:コード　H3:商品名　I3:取引口座　J3:数量
      K3:約定単価　L3:約定金額　M3:ATR　N3:ストップライン
      O3:損益　P3:メモ　Q3:取引ID　R3:前回ID
      S3:最新行　T3:前残数量　U3:前残簿価　V3:平均取得単価
      W3:残数量　X3:残簿価　Y3:最終ストップライン　Z3:買い回数累計
      AA3:売り回数累計　AB3:買い金額　AC3:売り金額　AD3:利益額
      AE3:損失額　AF3:合計損益　AG3:勝ち数　AH3:負け数
  • A3からAH3までを範囲選択して[挿入]タブから[テーブル]をクリック
    • [先頭行をテーブルの見出しとして使用する]にチェックをつけて[OK]をクリック
  • [テーブルデザイン]タブを開き[テーブル名:]に「tblTx」と入力
  • [区分]をプルダウン設定
    • C4セルを範囲選択して[データ]タブから[データの入力規則]を開き、[データの入力規則]をクリック
    • [入力値の種類:]から「リスト」を選択し、[元の値:]に以下を入力 
      • 現物,信用
  • [売買]をプルダウン設定
    • D4セルを範囲選択して[データ]タブから[データの入力規則]を開き、[データの入力規則]をクリック
    • [入力値の種類:]から「リスト」を選択し、[元の値:]に以下を入力 
      • 買い,売り
  • [商品リスト]をプルダウン設定
    • H4セルを範囲選択して[データ]タブから[データの入力規則]を開き、[データの入力規則]をクリック
    • [入力値の種類:]から「リスト」を選択し、[元の値:]に以下を入力 
      • =商品リスト
  • 以下の対象セルに数式を入力
    • B1：「商品・資産管理」シートに入力している総投資用資金を反映させる 
      • =商品・資金管理!$B$1
    • B2：現在投資に使用している資金を自動表示 
      • =SUMIF(tblTx[最新行], 1, tblTx[残簿価])
    • C2：資金が総投資用資金を超過していないかどうかのステータス表示 
      • =IF(B2>B1, "⚠ 資金超過：オーバーレバレッジです", "資金状況：正常")
    • A4：[日付]の入力から自動反映して表示 
      • =IF([@日付]="","",YEAR([@日付]))
    • E4：[商品リスト]で選択した商品から[グループ]を自動表示 
      • =IF([@商品名]="","",XLOOKUP([@商品名],tblItem[商品名],tblItem[グループ],""))
    • F4：[商品リスト]で選択した商品から[CD]を自動表示 
      • =IF([@商品名]="","",XLOOKUP([@商品名],tblItem[商品名],tblItem[CD],""))
    • G4：[商品リスト]で選択した商品から[コード]を自動表示 
      • =IF([@商品名]="","",XLOOKUP([@商品名],tblItem[商品名],tblItem[コード],""))
    • L4：入力した[数量]と[約定単価]から[約定金額]を自動計算 
      • =IF(OR([@数量]="",[@約定単価]=""),"",IF([@グループ]="3_投資信託",([@数量]*[@約定単価])/10000,[@数量]*[@約定単価]))
    • N4：入力した[ATR]から[ストップライン]を自動計算 
      • =IF(OR(AND([@区分]="現物",[@売買]="買い"), [@区分]="信用"), IF(AND([@約定単価]<>"",[@ATR]<>""), IF([@売買]="買い",[@約定単価]-[@ATR]*2, [@約定単価]+[@ATR]*2), ""), "")
    • O4：同口座・同区分の同商品で売買があった場合に[損益]を自動算出 
      • =IF(AND([@前残数量]<>0,OR(AND([@区分]="現物",[@売買]="売り"),AND([@区分]="信用",[@売買]="売り"),AND([@区分]="信用",[@売買]="買い"))),IF([@数量]>ABS([@前残数量]),"⚠数量エラー",([@約定金額]-ABS([@前残簿価]/[@前残数量])*[@数量])*IF(OR(AND([@区分]="現物",[@売買]="売り"),AND([@区分]="信用",[@売買]="売り")),1,-1)),"")
    • Q4：他の数式の計算用 
      • =ROW()-ROW(INDEX([日付],1))+1
    • R4：他の数式の計算用 
      • =IFERROR(MAXIFS([取引ID],[コード],[@コード],[取引口座],[@取引口座],[区分],[@区分],[取引ID],"<"&[@取引ID]),0)
    • S4：他の数式の計算用 
      • =--([@取引ID]=MAXIFS([取引ID],[コード],[@コード],[取引口座],[@取引口座],[区分],[@区分]))
    • T4：[残数量]の計算用 
      • =IFERROR(XLOOKUP([@前回ID],[取引ID],[残数量],0),0)
    • U4：[残簿価]の計算用 
      • =IFERROR(XLOOKUP([@前回ID],[取引ID],[残簿価],0),0)
    • V4：同口座・同区分に残っている同商品の[平均取得単価]を自動算出 
      • =IFERROR(IF([@残数量]=0,"",ABS([@残簿価]/[@残数量])),"")
    • W4：同口座・同区分に残っている同商品の[残数量]を自動算出 
      • =IF([@取引ID]=1, IF([@売買]="買い", [@数量], -[@数量]), IF([@売買]="買い", [@前残数量]+[@数量], [@前残数量]-[@数量]))
    • X4：同口座・同区分に残っている同商品の[残簿価]を自動算出 
      • =IF([@残数量]=0, 0, IF(ABS([@残数量]) < ABS([@前残数量]), [@前残簿価] * ([@残数量] / [@前残数量]), [@前残簿価] + [@約定金額]))
    • Y4：同口座・同区分の同商品の最後に入力されている[ATR]を保存 
      • =LET(c,[@コード],a,[@取引口座],t,[@区分],IF(OR(c="",a="",t=""),"",IFERROR(LOOKUP(2,1/(([コード]=c)*([取引口座]=a)*([区分]=t)*([ストップライン]<>"")),[ストップライン]),"")))
    • Z4：同商品の「買い」の回数を累計して計算 
      • =LET(prev,IFERROR(XLOOKUP([@前回ID],[取引ID],[買い回数累計],0),0),prev+IF([@売買]="買い",1,0))
    • AA4：同商品の「売り」の回数を累計して計算 
      • =LET(prev,IFERROR(XLOOKUP([@前回ID],[取引ID],[売り回数累計],0),0),prev+IF([@売買]="売り",1,0))
    • AB4：[約定金額]が「買い」の場合に[買い金額]として保存 
      • =IF([@売買]="買い",[@約定金額],0)
    • AC4：[約定金額]が「売り」の場合に[売り金額]として保存 
      • =IF([@売買]="売り",[@約定金額],0)
    • AD4：他のシートで平均利益を出すために使用 
      • =IF([@損益]>0, [@損益], 0)
    • AE4：他のシートで平均損失を出すために使用 
      • =IF([@損益]<0, ABS([@損益]), 0)
    • AF4：同口座・同区分・同商品の合計した損益を自動算出 
      • =LET(prev,IF([@前回ID]=0,0,XLOOKUP([@前回ID],[取引ID],[合計損益],0)),cur,IF([@損益]="",0,[@損益]),prev+cur)
    • AG4：損益がプラスの際に[勝ち回数]として保存 
      • =IF(AND(ISNUMBER([@損益]), [@損益]>0), 1, 0)
    • AH4：損益がマイナスの際に[負け回数]として保存 
      • =IF(AND(ISNUMBER([@損益]), [@損益]<0), 1, 0)
  • 金額が表示される列やセルは、右クリックの[セルの書式設定]から表示形式を変更しておくのがおススメ
    • 金額表示列：B1セル・B2セル・K列（約定単価）・L列（約定金額）・M列（ATR）・N列（ストップライン）・O列（損益）
    • その他の金額が表示される列は非表示推奨のため、とくに形式変更は必要なし
  • 通常利用時に不要な列を非表示設定にしておく
    • 非表示推奨列：E～G列・Q～AH列
  • 3行目までを固定表示にしておく
    • A4セルを範囲選択して[表示]タブから[ウィンドウ枠の固定]を選択
「取引ログ」シートの作成手順
  • ①
    新しいシートを作成して、シート名を「取引ログ」に変更する
  • ②
    各セルに見出しとなる単語を入力していく

    A1:総投資用資金:　A2:現投入資金:　A3:年　B3:日付
    C3:区分　D3:売買　E3:グループ　F3:CD
    G3:コード　H3:商品名　I3:取引口座　J3:数量
    K3:約定単価　L3:約定金額　M3:ATR　N3:ストップライン
    O3:損益　P3:メモ　Q3:取引ID　R3:前回ID
    S3:最新行　T3:前残数量　U3:前残簿価　V3:平均取得単価
    W3:残数量　X3:残簿価　Y3:最終ストップライン　Z3:買い回数累計
    AA3:売り回数累計　AB3:買い金額　AC3:売り金額　AD3:利益額
    AE3:損失額　AF3:合計損益　AG3:勝ち数　AH3:負け数

  • ③
    A3からAH3までを範囲選択して[挿入]タブから[テーブル]をクリック

    [先頭行をテーブルの見出しとして使用する]にチェックをつけて[OK]をクリック

  • ④
    [テーブルデザイン]タブを開き[テーブル名:]に「tblTx」と入力
  • ⑤
    [区分]をプルダウン設定

    C4セルを範囲選択して[データ]タブから[データの入力規則]を開き、[データの入力規則]をクリック

    [入力値の種類:]から「リスト」を選択し、[元の値:]に以下を入力

    現物,信用
  • ⑥
    [売買]をプルダウン設定

    D4セルを範囲選択して[データ]タブから[データの入力規則]を開き、[データの入力規則]をクリック

    [入力値の種類:]から「リスト」を選択し、[元の値:]に以下を入力

    買い,売り

  • ⑦
    [商品リスト]をプルダウン設定

    H4セルを範囲選択して[データ]タブから[データの入力規則]を開き、[データの入力規則]をクリック

    [入力値の種類:]から「リスト」を選択し、[元の値:]に以下を入力

    商品名
  • ⑧
    対象セルに手順⑧の数式を入力

  • ⑨
    金額が表示される列やセルは、右クリックの[セルの書式設定]から表示形式を変更しておくのがおススメ

    金額表示列：B1セル・B2セル・K列（約定単価）・L列（約定金額）・M列（ATR）・N列（ストップライン）・O列（損益）

    その他の金額が表示される列は非表示推奨のため、とくに形式変更は必要なし

  • ⑩
    通常利用時に不要な列を非表示設定にしておく

    非表示推奨列：E～G列・Q～AH列

  • ⑪
    3行目までを固定表示にしておく

    A4セルを範囲選択して[表示]タブから[ウィンドウ枠の固定]を選択

「取引ログ」シートの使い方は、「Excelを使ったタートルズトレード流『Excelの資産運用ログ』の使い方」にて解説している。

Excelを使ったタートルズトレード流『Excelの資産運用ログ』の使い方
タートルズ流の投資手法を参考にした『Excelの資産運用ログ』システムを公開。おまかせ運用の投資が主流の今、あえて自作Excelで管理する筆者の事例を提示する。
senjutsu-automatos.com

◆

『Excelの資産運用ログ』――「データ」シートの作成手順

  • 新しいシートを作成して、シート名を「データ」に変更する
  • 各セルに見出しとなる単語を入力していく
    • A1:総投資用資金:　A2:現投入資金:　A3:グループ　B3:CD
      C3:コード　D3:商品名　E3:区分　F3:取引口座
      G3:ステータス　H3:残数量　I3:平均単価　J3:残簿価
      K3:確定損益額　L3:最終ストップライン　M3:参考現在価格　N3:参考損益額
      O3:参考アラート
  • M3からO3までの見出しを範囲選択して、[挿入]タブから[テーブル]をクリック
    • [先頭行をテーブルの見出しとして使用する]にチェックをつけて[OK]をクリック
  • [テーブルデザイン]タブを開いて[テーブル名:]に「tblDate」と入力
  • A3からL3までの見出しはテーブル化しないため、自由にデザインする
  • 以下の対象セルに数式を入力
    • B1：「商品・資産管理」シートに入力している総投資用資金を反映させる 
      • =商品・資金管理!$B$1
    • B2：現在投資に使用している資金を自動表示 
      • =SUMIF(tblTx[最新行], 1, tblTx[残簿価])
    • C2：資金が総投資用資金を超過していないかどうかのステータス表示 
      • =IF(B2>B1, "⚠ 資金超過：オーバーレバレッジです", "資金状況：正常")
    • A4：[グループ]から[最終ストップライン]までのデータを「取引ログ」から自動抽出して表示 
      • =FILTER(CHOOSE({1,2,3,4,5,6,7,8,9,10,11,12},tblTx[グループ],tblTx[CD],tblTx[コード],tblTx[商品名],tblTx[区分],tblTx[取引口座],IF(tblTx[残数量]=0,"決済完了",IF(tblTx[残数量]<0,"空売り中","保有中")),tblTx[残数量],IF(tblTx[残数量]=0,"",ABS(tblTx[残簿価]/tblTx[残数量])),tblTx[残簿価],tblTx[合計損益],tblTx[最終ストップライン]),tblTx[最新行]=1,"")
    • N4：[参考現在価格]に入力した価格での損益額を参考値として表示 
      • =IF(G4="決済完了","⚠確定済み",IF(OR(M4="",M4=0),"入力待ち",IF(G4="空売り中",(I4-M4)*ABS(H4),(M4-I4)*H4)))
    • O4：[参考現在価格]に入力した価格での「増し玉」「保持」「損切り」ジャッジを参考表示 
      • =IF(G4="決済完了","",LET(lastAtr,IFERROR(XLOOKUP(1,(tblTx[コード]=C4)*(tblTx[取引口座]=F4)*(tblTx[区分]=B4)*(tblTx[最新行]=1),tblTx[ATR],XLOOKUP(C4,商品・資金管理!C:C,商品・資金管理!F:F,0)),0),IF(OR(M4=0,M4="",lastAtr=0),"入力待ち",IF(G4="保有中",IF(M4>=I4+(0.5*lastAtr),"★増し玉目安",IF(M4<=I4-(2*lastAtr),"⚠ストップ目安","保持")),IF(G4="空売り中",IF(M4<=I4-(0.5*lastAtr),"★増し玉目安",IF(M4>=I4+(2*lastAtr),"⚠ストップ目安","保持")),"保持")))))
  • 金額が表示される列やセルは、右クリックの[セルの書式設定]から表示形式を変更しておくのがおススメ
    • 金額表示列：B1セル・B2セル・I列（平均単価）～N列（参考損益額）
  • 3行目までを固定表示にしておく
    • A4セルを範囲選択して[表示]タブから[ウィンドウ枠の固定]を選択
「データ」シートの作成手順
  • ①
    新しいシートを作成して、シート名を「データ」に変更する
  • ②
    各セルに見出しとなる単語を入力していく

    A1:総投資用資金:　A2:現投入資金:　A3:グループ　B3:CD
    C3:コード　D3:商品名　E3:区分　F3:取引口座
    G3:ステータス　H3:残数量　I3:平均単価　J3:残簿価
    K3:確定損益額　L3:最終ストップライン　M3:参考現在価格　N3:参考損益額
    O3:参考アラート

  • ③
    M3からO3までの見出しを範囲選択して、[挿入]タブから[テーブル]をクリック

    [先頭行をテーブルの見出しとして使用する]にチェックをつけて[OK]をクリック

  • ④
    [テーブルデザイン]タブを開いて[テーブル名:]に「tblDate」と入力
  • ⑤
    A3からL3までの見出しはテーブル化しないため、自由にデザインする
  • ⑥
    対象セルに手順⑥の数式を入力
  • ⑦
    金額が表示される列やセルは、右クリックの[セルの書式設定]から表示形式を変更しておくのがおススメ

    金額表示列：B1セル・B2セル・I列（平均単価）～N列（参考損益額）

  • ⑧
    3行目までを固定表示にしておく

    A4セルを範囲選択して[表示]タブから[ウィンドウ枠の固定]を選択

「データ」シートの使い方は、「Excelを使ったタートルズトレード流『Excelの資産運用ログ』の使い方」にて解説している。

Excelを使ったタートルズトレード流『Excelの資産運用ログ』の使い方
タートルズ流の投資手法を参考にした『Excelの資産運用ログ』システムを公開。おまかせ運用の投資が主流の今、あえて自作Excelで管理する筆者の事例を提示する。
senjutsu-automatos.com

◆

『Excelの資産運用ログ』――「集計」シートの作成手順

  • 新しいシートを作成して、シート名を「集計」に変更する
  • A1セルを範囲選択して[挿入]タブから[ピポットテーブル]を開き、[テーブルまたは範囲から]をクリック
  • [テーブル/範囲:]に「tblTx」を入力して[OK]をクリック
  • [ピポットテーブル分析]タブを開き、[ピポットテーブル名:]に「ptblSpread」と入力
  • フィールドを右下のボックスに、以下のように振り分ける
    • フィルター：年・日付・取引口座・区分
    • 列：Σ値
    • 行：グループ・CD・商品名
    • Σ値：合計/買い金額・合計/売り金額・合計/損益
  • [デザイン]タブを開き、[レポートのレイアウト]から[表形式で表示]を選択
  • B列の[CD]の集計を右クリックして[“CD”の小計]をクリック
  • [ピポットテーブル分析]タブを開き、[フィールド/アイテム/セット]を開いて[集計フィールド]をクリック
  • [名前:]に「平均利益」、[数式:]に以下のように入力して[追加]をクリックし、[OK]をクリック 
    • =IF(勝ち数> 0,利益額/勝ち数, 0)
  • 同様に「平均損失」「勝率」「リスクリワード比率」「期待値」も作成していく
    • 平均損失 
      • =IF(負け数> 0,損失額/負け数, 0)
    • 勝率 
      • =IFERROR(勝ち数/ (勝ち数+負け数), 0)
    • リスクリワード比率 
      • =IF(平均損失=0, 10,平均利益/平均損失)
    • 期待値 
      • = (勝率*平均利益) - ((1 -勝率) *平均損失)
  • 作成した「平均利益」「平均損失」「勝率」「リスクリワード比率」「期待値」のフィールドを[Σ値]のボックスに振り分ける
  • [Σ値]のボックスに振り分けた「合計/勝率」フィールドをクリックして、[値フィールドの設定]を開き、表示形式を「パーセンテージ」に変更する
    • 左下の[表示形式]をクリックして開く
    • [分類:]を「パーセンテージ」にして[小数点以下の桁数:]を「1」にして[OK]をクリック
  • [Σ値]のボックスに振り分けた「合計/リスクリワード比率」フィールドをクリックして、[値フィールドの設定]を開き、表示形式を「数値」に変更する
    • 左下の[表示形式]をクリックして開く
    • [分類:]を「数値」にして[小数点以下の桁数:]を「2」に設定し、[負の数の表示形式:]を「1234.10」にして[OK]をクリック
「集計」シートの作成手順
  • ①
    新しいシートを作成して、シート名を「集計」に変更する
  • ②
    A1セルを範囲選択して[挿入]タブから[ピポットテーブル]を開き、[テーブルまたは範囲から]をクリック
  • ③
    [テーブル/範囲:]に「tblTx」を入力して[OK]をクリック
  • ④
    [ピポットテーブル分析]タブを開き、[ピポットテーブル名:]に「ptblSpread」と入力
  • ⑤
    フィールドを右下のボックスに、以下のように振り分ける
    • フィルター：年・日付・取引口座・区分
    • 列：Σ値
    • 行：グループ・CD・商品名
    • Σ値：合計/買い金額・合計/売り金額・合計/損益
  • ⑥
    [デザイン]タブを開き、[レポートのレイアウト]から[表形式で表示]を選択
  • ⑦
    B列の[CD]の集計を右クリックして[“CD”の小計]をクリック
  • ⑧
    [ピポットテーブル分析]タブを開き、[フィールド/アイテム/セット]を開いて[集計フィールド]をクリック
  • ⑨
    [名前:]に「平均利益」、[数式:]に以下のように入力して[追加]をクリックし、[OK]をクリック

    =IF(勝ち数> 0,利益額/勝ち数, 0)

  • ⑩
    同様に「平均損失」「勝率」「リスクリワード比率」「期待値」も作成していく
    • 平均損失 
      • =IF(負け数> 0,損失額/負け数, 0)
    • 勝率 
      • =IFERROR(勝ち数/ (勝ち数+負け数), 0)
    • リスクリワード比率 
      • =IF(平均損失=0, 10,平均利益/平均損失)
    • 期待値 
      • = (勝率*平均利益) - ((1 -勝率) *平均損失)
  • ⑪
    作成した「平均利益」「平均損失」「勝率」「リスクリワード比率」「期待値」のフィールドを[Σ値]のボックスに振り分ける
  • ⑫
    [Σ値]のボックスに振り分けた「合計/勝率」フィールドをクリックして、[値フィールドの設定]を開き、表示形式を「パーセンテージ」に変更する

    左下の[表示形式]をクリックして開く

    [分類:]を「パーセンテージ」にして[小数点以下の桁数:]を「1」にして[OK]をクリック

  • ⑬
    [Σ値]のボックスに振り分けた「合計/リスクリワード比率」フィールドをクリックして、[値フィールドの設定]を開き、表示形式を「数値」に変更する

    左下の[表示形式]をクリックして開く

    [分類:]を「数値」にして[小数点以下の桁数:]を「2」に設定し、[負の数の表示形式:]を「1234.10」にして[OK]をクリック

「集計」シートの使い方は、「Excelを使ったタートルズトレード流『Excelの資産運用ログ』の使い方」にて解説している。

Excelを使ったタートルズトレード流『Excelの資産運用ログ』の使い方
タートルズ流の投資手法を参考にした『Excelの資産運用ログ』システムを公開。おまかせ運用の投資が主流の今、あえて自作Excelで管理する筆者の事例を提示する。
senjutsu-automatos.com

◆

『Excelの資産運用ログ』の紹介と「使い方」

『Excelの資産運用ログ』のシステムの紹介（用語解説）や具体的な利用方法は、別記事の「『Excelの資産運用ログ』の紹介」「『Excelの資産運用ログ』の使い方」にて解説している。

Excelを使ったタートルズトレード流『Excelの資産運用ログ』の紹介
タートルズ流の投資手法を参考にした『Excelの資産運用ログ』システムを公開。おまかせ運用の投資が主流の今、あえて自作Excelで管理する筆者の事例を提示する。
senjutsu-automatos.com
Excelを使ったタートルズトレード流『Excelの資産運用ログ』の使い方
タートルズ流の投資手法を参考にした『Excelの資産運用ログ』システムを公開。おまかせ運用の投資が主流の今、あえて自作Excelで管理する筆者の事例を提示する。
senjutsu-automatos.com
タイトルとURLをコピーしました